AM2
Андрей

 
Уровень 35
Добрейшей души человек!

  Торгую в компаниях:


Группа "Программирование на MQL"

Рейтинг 280


Обсуждаем здесь вопросы разработки экспертов, делимся опытом, выкладываем уроки.

Внимание! Если Вы хотите заказать советник, то Вам в группу «Заказы на разработку советников»


Лучшее от AM2



100% ордеров в плюс или тысячи процентов годовых Комментариев 19
2016-12-21 20:18:10Рейтинг 0

Экспорт сигналов из МТ4 в Telegram Комментариев 8
2020-11-25 19:42:10Рейтинг 0

Советник - откусыватель убыточной позиции Комментариев 24
2017-05-28 14:02:20Рейтинг 0

На какие "Машки" больше всего смотрят "Нонки" Комментариев 33
2015-11-07 02:52:18Рейтинг 0

Запускаем стороннее приложение и выключаем компьютер с помощью средств MQL Комментариев 3
2017-10-22 13:05:55Рейтинг 0

Как заставить работать советник на нестандартном таймфрейме

Совсем недавно в группе «Стол заказов MQL» были размещены два подобных заказа, с просьбой переписать советник для работы на нестандартном таймфрейме:
zakaz.opentraders.ru/31412.html
zakaz.opentraders.ru/31316.html

На обычных графиках советники работали, а на оффлайновых улыбались но отказывались торговать. Чтобы решить этот вопрос, я перелопатил форумы, но так и не нашел приемлемого решения.

Были такие рекомендации:

«В файл WinUser32.mqh вставить строчку 

int RegisterWindowMessageW(string lpstring);


В скрипт period_converter.mq4 вставить строку 

int MT4InternalMsg = RegisterWindowMessageW(«MetaTrader4_Internal_Message»); //incoming tick for EAs


и строку 

PostMessageW(hwnd,MT4InternalMsg,2,1); //incoming tick for EAs»


Или такие:

И какая разница, на каком таймфрейме запускать этот советник?

Пример. Таймфрейм H1. У нас есть MA simple 24.
На таймфрейме M5 чтобы отобразить эту MA надо период у нее указать 288 (60/5*24). И эта будет таже MA!

Если вы используете таймфрейм M3, к примеру, и у вас там MA simple 32 стоит, к примеру.
То откройте таймфрейм M1 и запустите там MA simple 96 — и вы увидите, то это таже MA.
Так и запустите советник на таймфрейме M1 с параметрами MA 96.

Да если например на таймфрейте Н1 у нас есть МА Exponential 24 и МА Exponential 10;
То соответственно на М5 надо отобразить 288 (60/5*24) и 120 (60/5*10), то графики совпадают, но при условии если цены закрытия совпадают (например, CLOSE= CLOSE; LOW= LOW)

Но если поставить цены закрытия на 288 CLOSE и на 120 LOW, а на Н1 24 CLOSE и на 10 LOW, то построение средних отличаются на графиках М5 от Н1.


Общими усилиями, а вернее с помощью более опытных коллег, нашлось очень простое решение этого вопроса.

Пусть у нас есть советник, торгующий на превышении одной машки над другой:



Вот его код:


//+------------------------------------------------------------------+
//|                                                      2Mashki.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property description "Simple expert advisor"

extern int StopLoss     = 1200;
extern int TakeProfit   = 1400;
extern int Slip         = 50;
extern int MA1Period    = 10;
extern int MA2Period    = 50;
extern int Magic        = 123;
extern double Lots      = 0.1;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }  
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll()
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==OP_SELL)
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double ma1=iMA(NULL,0,MA1Period,0,MODE_EMA,PRICE_CLOSE,1);
   double ma2=iMA(NULL,0,MA2Period,0,MODE_EMA,PRICE_CLOSE,2);

//---- buy 
   if(ma1>ma2)
     {
      PutOrder(0,Ask);
     }
//---- sell   
   if(ma1<ma2)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ClosePos()
  {
   double ma1=iMA(NULL,0,MA1Period,0,MODE_EMA,PRICE_CLOSE,1);
   double ma2=iMA(NULL,0,MA2Period,0,MODE_EMA,PRICE_CLOSE,2);

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(ma1<ma2)
                 {
                  CloseAll();
                 }
              }
            if(OrderType()==OP_SELL)
              {
               if(ma1>ma2)
                 {
                  CloseAll();
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Start function                                                   |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()<1)
     {
      OpenPos();
     }
   else ClosePos();
  }
//+------------------------------------------------------------------+


Бросаем наш советник на оффлайн график и конечно же ничего не происходит.



Чтобы советник торговал на М3 создадим таймер OnTimer(), добавим функцию обновления котировок RefreshRates() и поместим в таймер функцию обработки тиков OnTick().


void OnTimer()
  {
   RefreshRates(); 
   OnTick(); 
  }


Чтобы таймер работал, при инициализации зададим периодичность работы таймера с помощью функции EventSetMillisecondTimer()
В скобках укажем количество миллисекунд через которое необходимо генерировать событие таймера.

int OnInit()
  {
//---
   EventSetMillisecondTimer(1);
//---
   return(INIT_SUCCEEDED);
  }


При деинициализации эксперта удалим созданный таймер:


void OnDeinit(const int reason)
  {
   EventKillTimer();
  }


После таких простейших преобразований наш советник примет следующий вид: 


//+------------------------------------------------------------------+
//|                                                      2Mashki.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property description "Simple expert advisor"

extern int StopLoss     = 1200;
extern int TakeProfit   = 1400;
extern int Slip         = 50;
extern int MA1Period    = 10;
extern int MA2Period    = 50;
extern int Magic        = 123;
extern double Lots      = 0.1;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   EventSetMillisecondTimer(1);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   EventKillTimer();
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll()
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),Slip,White);
              }
            if(OrderType()==OP_SELL)
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),Slip,White);
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
   double ma1=iMA(NULL,0,MA1Period,0,MODE_EMA,PRICE_CLOSE,1);
   double ma2=iMA(NULL,0,MA2Period,0,MODE_EMA,PRICE_CLOSE,2);

//---- buy 
   if(ma1>ma2)
     {
      PutOrder(0,Ask);
     }
//---- sell   
   if(ma1<ma2)
     {
      PutOrder(1,Bid);
     }
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ClosePos()
  {
   double ma1=iMA(NULL,0,MA1Period,0,MODE_EMA,PRICE_CLOSE,1);
   double ma2=iMA(NULL,0,MA2Period,0,MODE_EMA,PRICE_CLOSE,2);

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY)
              {
               if(ma1<ma2)
                 {
                  CloseAll();
                 }
              }
            if(OrderType()==OP_SELL)
              {
               if(ma1>ma2)
                 {
                  CloseAll();
                 }
              }
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Start function                                                   |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(CountTrades()<1)
     {
      OpenPos();
     }
   else ClosePos();
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnTimer()
  {
   RefreshRates();
   OnTick();
  }
//+------------------------------------------------------------------+


И в таком виде уже на графике откроет сделку:



Таким образом, потребуется не больше 5 минут чтобы переписать обычный советник на эксперт для нестандартных таймфреймов.

Скачать код советника можно по ссылке: www.opentraders.ru/downloads/1113/
  • +2
  • Просмотров: 13120
  • 21 марта 2016, 17:43
  • AM2
Понравилcя материал? Не забудьте поставить плюс и поделиться в социальной сети!

Вступите в группу "Программирование на MQL", чтобы следить за обновлениями
ПРИСОЕДИНИТЬСЯ К ГРУППЕ
присоединиться
Следующая запись в группе  
Торгуем в тестере вручную. MT4
13 марта 2016
02 апреля 2016

Брокер для ваших роботов, 15 лет на рынке

Комментарии (0)


Зарегистрируйтесь или авторизуйтесь, чтобы оставить комментарий