До сегодняшнего дня я думал что писать панели управления это очень непростая задача. Когда я попробовал набросать простенький вариант, все оказалось иначе.

Пусть в нашей панели будет всего три кнопки «BUY», «SELL», «CLOSE». Вы спросите почему так мало? Да только потому чтобы показать принцип написания панелей, люди знакомые c MQL4 очень быстро приспособят данный пример под свои потребности.

Реализуем нашу панель в виде советника. Первым делом создадим функцию установки объекта «Кнопка». Здесь мы пропишем размеры кнопки, наименование шрифта, цвет текста и т.д.

void PutButton(string name,int x,int y,string text)
  {
   ObjectCreate(0,name,OBJ_BUTTON,0,0,0);

//--- установим координаты кнопки
   ObjectSetInteger(0,name,OBJPROP_XDISTANCE,x);
   ObjectSetInteger(0,name,OBJPROP_YDISTANCE,y);
//--- установим размер кнопки
   ObjectSetInteger(0,name,OBJPROP_XSIZE,80);
   ObjectSetInteger(0,name,OBJPROP_YSIZE,30);
//--- установим угол графика, относительно которого будут определяться координаты точки
   ObjectSetInteger(0,name,OBJPROP_CORNER,2);
//--- установим текст
   ObjectSetString(0,name,OBJPROP_TEXT,text);
//--- установим шрифт текста
   ObjectSetString(0,name,OBJPROP_FONT,"Arial");
//--- установим размер шрифта
   ObjectSetInteger(0,name,OBJPROP_FONTSIZE,12);
//--- установим цвет текста
   ObjectSetInteger(0,name,OBJPROP_COLOR,Red);
//--- установим цвет фона
   ObjectSetInteger(0,name,OBJPROP_BGCOLOR,White);
//--- установим цвет границы
   ObjectSetInteger(0,name,OBJPROP_BORDER_COLOR,Blue);
  }

При инициализации советника создадим необходимые нам кнопки:

int OnInit()
  {
   PutButton("B",50,50,"BUY");
   PutButton("S",150,50,"SELL");
   PutButton("C",250,50,"CLOSE");

   return(INIT_SUCCEEDED);
  }

Далее создадим функцию установки ордера:

void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
     }

   r=OrderSend(NULL,type,0.1,NormalizeDouble(price,Digits),100,0,0,"",123,0,clr);
   return;
  }

И функцию закрытия всех ордеров:

void ClosePos(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),100,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),100,White);
              }
           }
        }
     }
  } 

Чтобы наш советник понимал нажатие мышкой на кнопке, пропишем наши функции в обработчике события OnChartEvent.

virtual void  OnChartEvent( 
   const int     id,       // идентификатор события 
   const long&   lparam,   // параметр события типа long 
   const double  dparam,   // параметр события типа double 
   const string  sparam    // параметр события типа string 
   )

Параметры
id
[in] Идентификатор события.

lparam
[in] Параметр события типа long.

dparam
[in] Параметр события типа double.

sparam
[in] Параметр события типа string.

Возвращаемое значение
Нет.

Наш обработчик будет выглядеть следующим образом:

void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
//--- проверим событие на нажатие кнопки мышки
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      string clickedChartObject=sparam;
      //--- если нажатие на объекте с именем "B"
      if(clickedChartObject=="B")
        {
         PutOrder(0,Ask);
        }
      //--- если нажатие на объекте с именем "S"
      if(clickedChartObject=="S")
        {
         PutOrder(1,Bid);
        }
      //--- если нажатие на объекте с именем "C"
      if(clickedChartObject=="C")
        {
         ClosePos();
        }

      ChartRedraw();// принудительно перерисуем все объекты на графике
     }
  }

И вот наша панель практически готова:

//+------------------------------------------------------------------+
//|                                                        Panel.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+

#property copyright "Copyright 2015, AM2"
#property link      "https://www.forexsystems.biz"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   PutButton("B",50,50,"BUY");
   PutButton("S",150,50,"SELL");
   PutButton("C",250,50,"CLOSE");

   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutButton(string name,int x,int y,string text)
  {
   ObjectCreate(0,name,OBJ_BUTTON,0,0,0);

//--- установим координаты кнопки
   ObjectSetInteger(0,name,OBJPROP_XDISTANCE,x);
   ObjectSetInteger(0,name,OBJPROP_YDISTANCE,y);
//--- установим размер кнопки
   ObjectSetInteger(0,name,OBJPROP_XSIZE,80);
   ObjectSetInteger(0,name,OBJPROP_YSIZE,30);
//--- установим угол графика, относительно которого будут определяться координаты точки
   ObjectSetInteger(0,name,OBJPROP_CORNER,2);
//--- установим текст
   ObjectSetString(0,name,OBJPROP_TEXT,text);
//--- установим шрифт текста
   ObjectSetString(0,name,OBJPROP_FONT,"Arial");
//--- установим размер шрифта
   ObjectSetInteger(0,name,OBJPROP_FONTSIZE,12);
//--- установим цвет текста
   ObjectSetInteger(0,name,OBJPROP_COLOR,Red);
//--- установим цвет фона
   ObjectSetInteger(0,name,OBJPROP_BGCOLOR,White);
//--- установим цвет границы
   ObjectSetInteger(0,name,OBJPROP_BORDER_COLOR,Blue);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
     }

   r=OrderSend(NULL,type,0.1,NormalizeDouble(price,Digits),100,0,0,"",123,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ClosePos(int ot=-1)
  {
   bool cl;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol())
           {
            if(OrderType()==0 && (ot==0 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Bid,Digits),100,White);
              }
            if(OrderType()==1 && (ot==1 || ot==-1))
              {
               RefreshRates();
               cl=OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(Ask,Digits),100,White);
              }
           }
        }
     }
  }  
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {

  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
//--- проверим событие на нажатие кнопки мышки
   if(id==CHARTEVENT_OBJECT_CLICK)
     {
      string clickedChartObject=sparam;
      //--- если нажатие на объекте с именем "B"
      if(clickedChartObject=="B")
        {
         PutOrder(0,Ask);
        }

      if(clickedChartObject=="S")
        {
         PutOrder(1,Bid);
        }

      if(clickedChartObject=="C")
        {
         ClosePos();
        }

      ChartRedraw();// принудительно перерисуем все объекты на графике
     }
  }
//+------------------------------------------------------------------+

Проверим наше творение в действии:



Покупаем, нажимаем кнопку «BUY»:



Закрываем покупку, жмем «CLOSE»:



И наконец то проверяем кнопку «SELL»:



Точно таким же образом можно добавить на график кнопки с любыми другими необходимыми вам функциями или написать панель на MQL5, отличие будет только в содержании функций.

Скачать советник файлом можно по ссылке: www.opentraders.ru/downloads/1132/