Ранее мне встречались подобные формулы расчета лота, но мне захотелось во всем разобраться самостоятельно. Итак приступим.

Дано:

1. Депо 10000$.
2. Риск 2% от депо.
3. Стоп 1500 пунктов.

Найти: Лот?

Сначала определим какой убыток в долларах получим при риске 2% от депо:

Убыток = Депо * Риск.

10000 * 2% = 10000 * 2: 100 = 200 даляров  

Стоп в далярах также равен:

Убыток = Стоп * Лот.

Отсюда лот равен убыток делить на стоп.

Лот = Депо * Риск: Стоп.

А теперь в цифирях:

0.13 = 10000 * 2: 100: 1500

А вот так все это выглядит на мкл:

lot=NormalizeDouble((AccountEquity()*Risk/100)/StopLoss,Round);

Чтобы наглядно продемонстрировать правильность этой формулы напишем советник, который будет открывать позицию с указанным риском от стопа и выводить на экран значение лота от депо в настройках. Т.о. наш советник одновременно рассчитывает лот для ордера на счете на котором установлен и показывает на экране лот для депо введенного в настройках независимо от размера депо счета.

extern double Lots       = 0.1;      // лот
extern double Risk       = 2;        // риск
extern double Depo       = 1000;     // депо
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int BuySell       = 0;        // 1-Buy 2-Sell
extern int Round         = 2;        // округление 
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик

Рис.1. На экране рассчитан лот по параметрам в настройках.

И целиком код советника:

//+------------------------------------------------------------------+
//|                                                         Depo.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property version   "1.00"
#property strict

//--- Inputs
extern double Lots       = 0.1;      // лот
extern double Risk       = 2;        // риск
extern double Depo       = 1000;     // депо
extern int StopLoss      = 2000;     // лось
extern int TakeProfit    = 3000;     // язь
extern int BuySell       = 0;        // 1-Buy 2-Sell
extern int Round         = 2;        // округление 
extern int Slip          = 30;       // реквот
extern int Magic         = 123;      // магик
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   Comment("");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   Comment("");
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr=Green;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0) sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0) sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   if(AccountFreeMarginCheck(Symbol(),type,Lot())<=0)
     {
      Print("Недостаточно средств для открытия позиции объемом: ",Lot());
      return;
     }

   r=OrderSend(NULL,type,Lot(),NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double Lot()
  {
   double lot=Lots;
   double maxl=MarketInfo(NULL,MODE_MAXLOT);
   double minl=MarketInfo(NULL,MODE_MINLOT);

   if(Lots==0)
     {
      lot=NormalizeDouble((AccountEquity()*Risk/100)/StopLoss,Round);
     }

   if(lot<minl) lot=minl;
   if(lot>maxl) lot=maxl;

   return(lot);
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(OrdersTotal()<1)
     {
      if(BuySell==1) PutOrder(0,Ask);
      if(BuySell==2) PutOrder(1,Bid);
     }

   Comment("\n Lot: ",NormalizeDouble((Depo*Risk/100)/StopLoss,Round));
  }
//+------------------------------------------------------------------+

Скачать: www.opentraders.ru/downloads/1269/